007:programas-de-lectores

Microhobby 7. Año I, del 18 al 24 de diciembre de 1984

En los programas de lectores premiamos tu colaboración con 15.000 Pts.

Todas las semanas, MICROHOBBY publicará los programas que los lectores nos envíen, con las siguientes condiciones:

  1. Los programas deberán ser originales, inéditos y no haberse presentado a ninguna otra publicación.
  2. Se enviarán a MICROHOBBY en cinta cassette exenta de protección cotra copia y listado y autoejecución.
  3. Cada cinta irá acompañada de hoja explicativa de la utilidad y manejo del programa.
  4. En una sola cinta puede introducirse más de un programa.
  5. Una vez publicado, MICROHOBBY abonará al autor la cantidad de 15.000 pesetas en concepto de pago por colaboración.
  6. MICROHOBBY se reserva el derecho de publicación o no del programa.
  7. Además de la publicación de los programas de interés, MICROHOBBY realizará con todos los recibidos un sorteo mensual de un MICRODRIVE y su INTERFACE-1 correspondiente.

Bartolomé y Fco. Javier Román Antón :: Barcelona :: Premiado con 15.000 pts.

Spectrum 16K.

La velocidad y la destreza son los dos atributos necesarios para poder concluir felizmente el juego que les presentamos a continuación. Rápido y, aparentemente, fácil le mantendrá sujeto al monitor de su ordenador más tiempo del que desearía. Pruébelo.

En este juego nos convertimos en la «hormiga guía» de un grupo de atribuladas hormigas en busca de un nuevo hogar. Moviéndonos a una velocidad de vértigo, tenemos que encontrar un hormiguero nuevo evitando chocar con todo tipo de obstáculos, salimos de la pantalla o volver a recorrer el camino por el que vinimos.

Controlamos nuestros movimientos con las teclas del cursor.

El resto de las aclaraciones necesarias para jugar vienen incluidas en el propio programa.

hormigas.bas
    1 REM RESET  Bartolome y Francisco Javier Roman Anton
  100 REM INICIACION VARIABLES PROGRMA
  110 LET rc=0: LET j=23560
  130 DEF FN z(m)=INT (RND*m)+1
  200 GO SUB 8000
  500 BORDER 6: FLASH 0: PAPER 6: BRIGHT 1: CLS 
  510 PRINT FLASH 1; INK 0;AT 10,4;"H O R M I G U E R O S"
  520 PAUSE 10
  550 PRINT INK 0;AT 13,0;"CONDUCE A LAS HORMIGAS \a DESDE  LOS HORMIGUEROS VIEJOS \e HASTA  LOS NUEVOS \f, SIN CHOCAR CON    NINGUNA HORMIGA, MURO \g, NI     HORMIGUERO VIEJO \e."'"PARA ELLO USA LOS CURSORES";''"S U E R T E"
  560 PAUSE 100
  570 INK 2: PRINT AT 10,0;"\e": BEEP .1,30: PRINT AT 0,24;"\f": BEEP .2,50: FOR a=1 TO 24: PRINT AT 10,a;"\d": BEEP 0.0005,60: NEXT a: FOR a=10 TO 1 STEP -1: PRINT AT a,24;"\c": BEEP 0.0005,60: NEXT a
 1490 PAUSE 300
 1500 REM INICIACION VARIABLE PARTIDA
 1510 LET vi=5: LET pt=0: LET k=1
 1540 LET x=FN z(20): LET y=FN z(30)
 1550 DIM l(2,200)
 1560 LET l(1,1)=x: LET l(2,1)=y
 2000 REM INICIALIZACION VARIABLES JUEGO
 2010 IF k<200 THEN LET k=k+1
 2020 LET l(1,k)=FN z(20): LET l(2,k)=FN z(30)
 2040 LET g=FN z(4)+52
 2500 REM CUADRO
 2510 INK 4: PAPER 4: BORDER 4: CLS 
 2520 INK 7: PRINT AT 0,0;"\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g";AT 21,0;"\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g\g": FOR a=1 TO 20: PRINT AT a,0;"\g";AT a,31;"\g": NEXT a
 2800 LET p$="-----"( TO 5-LEN STR$ pt)+STR$ pt: LET r$="-----"( TO 5-LEN STR$ rc)+STR$ rc: LET v$="\b\b\b\b\b"( TO vi-1) +"....."( TO 6-vi)    
 3000 POKE 23624,98
 3010 PRINT #0;"PUNTOS:";p$;" RECORD:";r$;"  "; v$
 3500 REM DIBUJO HORMIGUEROS
 3510 FOR m=1 TO k-1
 3520 PRINT AT l(1,m),l(2,m); INK 1;"\e": BEEP .1,30
 3530 NEXT m
 3540 PRINT AT l(1,k),l(2,k); INK 3;"\f": BEEP .2,50
 3550 LET x=l(1,k-1): LET y=l(2,k-1)
 4500 REM TECLADO
 4510 LET t=PEEK j: IF t<=56 AND t>=53 THEN LET g=t
 4520 LET y=y+1*(y<31 AND g=56)-1*(y>0 AND g=53): LET x=x+1*(x<21 AND g=54)-1*(x>0 AND g=55)
 4700 REM CHOQUE MOVIMIENTO
 4710 IF ATTR (x,y)=100 THEN PRINT AT x,y; INK 0;CHR$ (91+g): BEEP 0.0005,60: GO TO 4500
 5000 GO TO 5100+(ATTR (x,y)-95)*100
 5200 REM HORMIGA
 5210 FOR a=0 TO 40: BEEP .005,-FN z(60): PRINT INK a/10;AT x,y;CHR$ (91+g): NEXT a
 5220 GO TO 6000
 5300 REM VIEJO
 5310 FOR a=0 TO -60 STEP -1: BEEP .01,a: NEXT a
 5320 GO TO 6000
 5500 REM NUEVO
 5510 FOR a=40 TO 0 STEP -1: BEEP a/1000,24: BEEP a/1000,23: BEEP a/1000,21: BEEP a/1000,19: BORDER a/10: NEXT a: BORDER 4
 5530 LET pt=pt+10
 5535 IF k/10=INT (k/10) THEN LET vi=vi+1: PRINT FLASH 1;AT 10,5;"VIDA EXTRA": PAUSE 200
 5540 GO TO 2000
 5900 REM PANTALLE
 5910 FOR a=0 TO 40: BEEP .0005,FN z(60): PRINT INK a/10;AT x,y;CHR$ (91+g): NEXT a
 6000 LET vi=vi-1: IF vi<>0 THEN GO TO 2500
 6010 BORDER 5: INK 0: PAPER 5: CLS 
 6020 IF pt<rc THEN GO TO 6100
 6030 PRINT FLASH 1;"NUEVO RECORD";AT 10,14;pt: INPUT "NOMBRE ";n$
 6040 LET rc=pt
 6100 FLASH 1: CLS 
 6120 PRINT OVER 1; FLASH 0;AT 10,5;"EL MEJOR";AT 10,5;"_________";AT 17,3;n$
 6130 PRINT #0;"PULSE TECLA PARA JUGAR"
 6150 PAUSE 0
 6200 GO TO 500
 8000 REM DEFINICION DE CARACTERES
 8010 DATA "c",40,146,124,56,254,56,124,146
 8020 DATA "b",146,124,56,254,56,124,146,40
 8030 DATA "a",73,42,190,63,190,42,73,0
 8040 DATA "d",146,84,125,254,125,84,146,0
 8050 DATA "e",30,63,127,255,255,254,252,48
 8060 DATA "f",6,7,237,252,252,126,62,6
 8080 DATA "G",170,170,85,85,170,170,85,85
 8400 FOR a=1 TO 7: READ a$: FOR b=0 TO 7: READ c: POKE USR a$+b,c: NEXT b: NEXT a
 8410 RETURN 
 9999 SAVE "HORMIGAS" LINE 1

Alberto González Garde :: Premiado con 15.000 pts.

Spectrum 48K.

Este programa está pensado para modificar el juego de caracteres del SPECTRUM convirtiéndolos, según el autor, en «letragorda» y, efectivamente, es así.

Se trata de una utilidad que puede tener cierta importancia si queremos que en nuestras propias aplicaciones aparezcan rótulos, listados o cualquier otra cosa distinta de lo normal.

Las instrucciones para conservar el código generado por el programa se detallan en éste con total claridad.

Julia Pérez Serrano :: Premiado con 15.000 pts.

Spectrum 16 K

Tenemos que situamos en otra galaxia, en donde la lucha por la supervivencia es el único fin de nuestra existencia. En una fortaleza aislada y rodeada por el enemigo, debemos demostrar nuestra puntería para rechazar el constante ataque al que nos tiene sometido.

Este es, en síntesis, el centro del juego que conseguirá, sin lugar a dudas, situarnos en otro siglo y hacernos protagonistas de una aventura galáctica.

Una vez situados, comprobaremos que somos el comando de la última fortaleza «Platínium» que dispone de cuatro turbo láser que apuntan directamente a las cuatro bases alienígenas que nos rodean. Desde estas mismas bases, recibiremos el constante ataque de los más sofisticados misiles capaces de desintegrar cualquier tipo de materia, incluso el platinium de nuestra base.

Nuestra misión será interceptar esos misiles en su trayectoria hacia nosotros, única manera de sobrevivir, pues nuestros láser nada pueden hacer contra sus bases. Para conseguirlo, tenemos cuatro mandos:

  • O: Dispara a la izquierda.
  • P: Dispara a la derecha.
  • Q: Dispara hacia abajo.
  • A: Dispara hacia arriba.

Atención, si se disparan dos láser a la vez, no responderá ninguno. Active sus reflejos y… suerte.

Francisco José Huidobro :: Premiado con 15.000 pts.

Spectrum 16 K

Se trata de una utilidad que nos calcula las funciones trigonométricas, seno, coseno, tangente, secante, cosecante, cotangente y sus inversas: arcoseno, arcocoseno y arco tangente.

En las primeras, podemos efectuar ia entrada de datos en grados o radianes; el programa nos avisará mediante el símbolo de infinito o valor no definido cuando sea necesario.

Las instrucciones están incluidas en el propio programa en forma de menú de opciones.

  • 007/programas-de-lectores.txt
  • Última modificación: d/m/Y H:i
  • por falvarez